autoit安裝adobe reader dc問題?

suchunta

最近在學autoit，安裝adobe reader dc離線版，可以將檔案執行，然後無法執行安裝，請問哪裡出錯了?
ShellExecute("e:\AcroRdrDC1900820071_zh_TW.exe")
WinWaitActive("Adobe Acrobat Reader DC (Continuous) - 設定","準備安裝 Adobe Acrobat Reader DC")
Send("!i")
WinWaitActive("Adobe Acrobat Reader DC (Continuous) - 設定","安裝程式已完成")
Send("!f")

gary8349

我有測試你的代碼
是可以正確執行安裝的...

使用這方法可能要注意以下幾點
1.該安裝程式需要為活動（激活）狀態，以及位於最上層
2.安裝途中不可以去點擊其他地方，以免Send失靈...
    （Send命令限於活動的視窗）
3.可以在腳本頭尾分別加上 BlockInput(1)、BlockInput(0)，
    用以鎖定滑鼠和鍵盤，降低失敗機率

1. 
   
2. BlockInput(1)
   
3. ShellExecute("e:\AcroRdrDC1900820071_zh_TW.exe")
   
4. WinWaitActive("Adobe Acrobat Reader DC (Continuous) - 設定","準備安裝 Adobe Acrobat Reader DC")
   
5. Send("!i")
   
6. WinWaitActive("Adobe Acrobat Reader DC (Continuous) - 設定","安裝程式已完成")
   
7. Send("!f")
   
8. BlockInput(0)
   

複製代碼

gary8349

以下為我的方法，僅供參考
推薦方法二

方法一：

1. #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
   
2. 
   
3. 
   
4. #AutoIt3Wrapper_UseX64=n
   
5. #NoTrayIcon
   
6. #RequireAdmin
   
7. 
   
8. 
   
9. ;;載入用以使用 防止重複執行（_Singleton） 語句
   
10. #include <Misc.au3>
    
11. 
    
12. FileChangeDir(@ScriptDir) ;;切換起始目錄工作目錄到腳本所在路徑
    
13. _Singleton(@ScriptName) ;;防止重複執行
    
14. 
    
15. 
    
16. ;;=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
    
17. 
    
18. 
    
19. ;;安裝程式的路徑
    
20. Global $sFile = @ScriptDir & '\AcroRdrDC1900820071_zh_TW.exe'
    
21. ;;第一個視窗的標題與類型
    
22. Global $Windows1 = '[Title:Adobe Acrobat Reader DC - 安裝程式; Class:#32770]'
    
23. ;;第二個視窗的標題與類型
    
24. Global $Windows2 = '[Title:Adobe Acrobat Reader DC (Continuous) - 設定; Class:MsiDialogCloseClass]'
    
25. 
    
26. BlockInput(1)
    
27. 
    
28. ;;執行安裝程式
    
29. ShellExecute($sFile)
    
30. 
    
31. ;;等待第一個視窗（解壓縮-AcroRdrDC1900820071_zh_TW.exe）
    
32. WinWait($Windows1, '正在解壓縮安裝檔案...')
    
33. 
    
34. ;;等待第二個視窗（解壓縮完的執行程式-setup.exe）
    
35. WinWaitActive($Windows2, '準備安裝 Adobe Acrobat Reader DC')
    
36. 
    
37. 
    
38. Send("!i")
    
39. 
    
40. 
    
41. WinWaitActive($Windows2, '安裝程式已完成')
    
42. 
    
43. 
    
44. Send("!f")
    
45. 
    
46. 
    
47. BlockInput(0)
    
48. 
    
49. 
    
50. MsgBox(64, '完成', '安裝已完成！', 5)
    
51. 
    
52. 
    
53. Exit
    
54. 
    

複製代碼

方法二：

1. #cs ＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
   
2. 
   
3.         Au3版本：3.3.14.5
   
4.         SciTE版本：3.6.6
   
5.         腳本作者：SHIWASU KAKERU / MicroDuo
   
6. 
   
7.         腳本功能：自動安裝 Adobe Reader DC 示例
   
8.         外部函數：PostMessage_UDF.au3（後臺執行）
   
9. 
   
10. #ce ＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿腳本開始＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
    
11. 
    
12. 
    
13. ;;腳本檢查
    
14. #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7
    
15. ;;exe不編譯為x64
    
16. #AutoIt3Wrapper_UseX64=n
    
17. ;;不顯示右下角系統匣圖標
    
18. #NoTrayIcon
    
19. ;;請求管理員權限
    
20. #RequireAdmin
    
21. 
    
22. 
    
23. ;;防止重複執行（_Singleton） 函數
    
24. #include <Misc.au3>
    
25. ;;_MouseClick 函數
    
26. #include <PostMessage_UDF.au3>
    
27. 
    
28. 
    
29. ;;切換起始目錄工作目錄到腳本所在路徑
    
30. FileChangeDir(@ScriptDir)
    
31. ;;防止重複執行
    
32. _Singleton(@ScriptName)
    
33. 
    
34. 
    
35. ;;=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=
    
36. 
    
37. 
    
38. ;;安裝程式的路徑
    
39. Global $sFile = @ScriptDir & '\AcroRdrDC1900820071_zh_TW.exe'
    
40. ;;第一個視窗的標題與類型
    
41. Global $Windows1 = '[Title:Adobe Acrobat Reader DC - 安裝程式; Class:#32770]'
    
42. ;;第二個視窗的標題與類型
    
43. Global $Windows2 = '[Title:Adobe Acrobat Reader DC (Continuous) - 設定; Class:MsiDialogCloseClass]'
    
44. ;;安裝按鈕
    
45. Global $btnInstallHandle = "[CLASS:Button; INSTANCE:4]"
    
46. ;;完成按鈕
    
47. Global $btnFinalHandle = "[CLASS:Button; INSTANCE:1]"
    
48. ;;宣告變數
    
49. Global $btnInstall, $btnFinal
    
50. 
    
51. 
    
52. ;;執行安裝程式
    
53. ShellExecute($sFile)
    
54. 
    
55. ;;等待第一個視窗（解壓縮-AcroRdrDC1900820071_zh_TW.exe）
    
56. WinWait($Windows1, '正在解壓縮安裝檔案...')
    
57. 
    
58. ;;等待第二個視窗（解壓縮完的執行程式-setup.exe）
    
59. WinWait($Windows2, '準備安裝 Adobe Acrobat Reader DC')
    
60. 
    
61. ;;按下 "安裝" 按鈕
    
62. $btnInstall = ControlGetHandle($Windows2,"",$btnInstallHandle) ;;取得 "安裝" 按鈕控件控制碼
    
63. _MouseClick(String($btnInstall), 'left', 50, 10) ;;滑鼠左鍵點擊 "安裝" 按鈕。 300, 324 => "安裝" 按鈕的相對（於安裝程式）座標
    
64. 
    
65. ;;等待安裝完成
    
66. WinWait($Windows2, '安裝程式已完成')
    
67. 
    
68. ;;按下 "完成" 按鈕
    
69. $btnFinal = ControlGetHandle($Windows2,"",$btnFinalHandle) ;;取得 "完成" 按鈕控件控制碼
    
70. _MouseClick(String($btnFinal), 'left', 50, 10) ;;滑鼠左鍵點擊 "完成" 按鈕。 50, 10 => "完成" 按鈕的相對（於安裝程式）座標
    
71. 
    
72. ;;等待視窗關閉
    
73. WinWaitClose($Windows2, '安裝程式已完成')
    
74. 
    
75. ;;完成提示
    
76. MsgBox(64, '完成', '安裝已完成！', 5)
    
77. 
    
78. ;;結束
    
79. Exit
    
80. 
    

複製代碼

gary8349

稍微題外話
如果要研究，不想每次都執行完等他解壓縮
可以用以下方法：

1.執行 AcroRdrDC1900820071_zh_TW.exe，等待解壓縮完成，不要進行下個動作
2.開啟Temp資料夾，可以用 ShellExecute(@TempDir)
3.找到數字資料夾，如：27948，大小約164MB
4.資料夾裡面有 config.bin、installer.bin，用7-Zip解壓縮installer.bin至 \installer 資料夾，得到以下檔案

5.直接對setup.exe進行操作即可

suchunta

感謝以上大大回復，我會測試看看